{
  pkgs,
  config,
  service_configs,
  lib,
  ...
}:
{
  imports = [
    (lib.serviceMountWithZpool "radarr" service_configs.zpool_ssds [
      service_configs.radarr.dataDir
    ])
    (lib.serviceMountWithZpool "radarr" service_configs.zpool_hdds [
      service_configs.torrents_path
    ])
    (lib.serviceFilePerms "radarr" [
      "Z ${service_configs.radarr.dataDir} 0700 ${config.services.radarr.user} ${config.services.radarr.group}"
    ])
    (lib.mkCaddyReverseProxy {
      subdomain = "radarr";
      port = service_configs.ports.private.radarr.port;
      auth = true;
    })
    (lib.mkArrSettingsService {
      name = "radarr";
      port = service_configs.ports.private.radarr.port;
      dataDir = service_configs.radarr.dataDir;
      # See services/arr/sonarr.nix for the rationale -- Radarr exhibits the same
      # bug, and has already imported ~10 FGT junk PROPER 2160p Remuxes (CF -9995)
      # over good releases because PreferAndUpgrade ignored the CF score.
      settings.mediamanagement.downloadPropersAndRepacks = "doNotPrefer";
    })
  ];

  services.radarr = {
    enable = true;
    dataDir = service_configs.radarr.dataDir;
    settings.server.port = service_configs.ports.private.radarr.port;
    settings.update.mechanism = "external";
  };

  users.users.${config.services.radarr.user}.extraGroups = [
    service_configs.media_group
  ];
}