Simon Gardling
d00ff42e8e
new site-config.nix holds values previously duplicated across hosts:
domain, old_domain, contact_email, timezone, binary_cache (url + pubkey),
dns_servers, lan (cidr + gateway), hosts.{muffin,yarn} (ip/alias/ssh_host_key),
ssh_keys.{laptop,desktop,ci_deploy}.
threaded through specialArgs on all three hosts + home-manager extraSpecialArgs +
homeConfigurations.primary + serverLib. service-configs.nix now takes
{ site_config } as a function arg and drops its https namespace; per-service
domains (gitea/matrix/ntfy/mollysocket/livekit/firefox-sync/grafana) are
derived from site_config.domain. ~15 service files and 6 vm tests migrated.
breakage fixes rolled in:
- home/progs/zen/dark-reader.nix: 5 stale *.gardling.com entries in
disabledFor rewritten to *.sigkill.computer (caddy 301s the old names so
these never fired and the new sigkill urls were getting dark-reader applied)
- modules/desktop-common.nix: drop unused hugepagesz=1G/hugepages=3
kernelParams (no consumer on mreow or yarn; xmrig on muffin still reserves
its own via services/monero/xmrig.nix)
verification: muffin toplevel is bit-identical to pre-refactor baseline.
mreow/yarn toplevels differ only in boot.json kernelParams + darkreader
storage.js (nix-diff verified). deployGuardTest and fail2banVaultwardenTest
(latter exercises site_config.domain via bitwarden.nix) pass.
99 lines
2.9 KiB
Nix
99 lines
2.9 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
inputs,
|
|
...
|
|
}:
|
|
let
|
|
baseSiteConfig = import ../site-config.nix;
|
|
baseServiceConfigs = import ../hosts/muffin/service-configs.nix { site_config = baseSiteConfig; };
|
|
testServiceConfigs = lib.recursiveUpdate baseServiceConfigs {
|
|
zpool_ssds = "";
|
|
minecraft.parent_dir = "/var/lib/minecraft";
|
|
minecraft.memory = rec {
|
|
heap_size_m = 1000;
|
|
};
|
|
};
|
|
|
|
# Create pkgs with nix-minecraft overlay and unfree packages allowed
|
|
testPkgs = import inputs.nixpkgs {
|
|
system = pkgs.stdenv.targetPlatform.system;
|
|
config.allowUnfreePredicate = pkg: builtins.elem (lib.getName pkg) [ "minecraft-server" ];
|
|
overlays = [
|
|
inputs.nix-minecraft.overlay
|
|
(import ../lib/overlays.nix)
|
|
];
|
|
};
|
|
in
|
|
testPkgs.testers.runNixOSTest {
|
|
name = "minecraft server startup test";
|
|
|
|
node.specialArgs = {
|
|
inherit inputs lib;
|
|
site_config = baseSiteConfig;
|
|
service_configs = testServiceConfigs;
|
|
username = "testuser";
|
|
};
|
|
|
|
nodes.machine =
|
|
{ lib, ... }:
|
|
{
|
|
imports = [
|
|
../services/minecraft.nix
|
|
];
|
|
|
|
# Force to 0 because no huge pages in vms ?
|
|
boot.kernel.sysctl."vm.nr_hugepages" = lib.mkForce 0;
|
|
|
|
# Enable caddy service (required by minecraft service)
|
|
services.caddy.enable = true;
|
|
|
|
# Enable networking for the test (needed for minecraft mods to download mappings)
|
|
networking.dhcpcd.enable = true;
|
|
|
|
# Disable the ZFS mount dependency service in test environment
|
|
systemd.services."minecraft-server-main_mounts".enable = lib.mkForce false;
|
|
|
|
# Remove service dependencies that require ZFS
|
|
systemd.services.minecraft-server-main = {
|
|
wants = lib.mkForce [ ];
|
|
after = lib.mkForce [ ];
|
|
requires = lib.mkForce [ ];
|
|
serviceConfig = {
|
|
Nice = lib.mkForce 0;
|
|
LimitMEMLOCK = lib.mkForce "infinity";
|
|
};
|
|
};
|
|
|
|
# Test-specific overrides only - reduce memory for testing
|
|
services.minecraft-servers.servers.main.jvmOpts = lib.mkForce "-Xmx1G -Xms1G";
|
|
|
|
# Create test user
|
|
users.users.testuser = {
|
|
isNormalUser = true;
|
|
uid = 1000;
|
|
extraGroups = [ "minecraft" ];
|
|
};
|
|
};
|
|
|
|
testScript = ''
|
|
start_all()
|
|
machine.wait_for_unit("multi-user.target")
|
|
|
|
# Wait for minecraft service to be available
|
|
machine.wait_for_unit("minecraft-server-main.service")
|
|
|
|
# Wait up to 60 seconds for the server to complete startup
|
|
with machine.nested("Waiting for minecraft server startup completion"):
|
|
try:
|
|
machine.wait_until_succeeds(
|
|
"grep -Eq '\\[[0-9]+:[0-9]+:[0-9]+\\] \\[Server thread/INFO\\]: Done \\([0-9]+\\.[0-9]+s\\)! For help, type \"help\"' /var/lib/minecraft/main/logs/latest.log",
|
|
timeout=120
|
|
)
|
|
except Exception:
|
|
print(machine.succeed("cat /var/lib/minecraft/main/logs/latest.log"))
|
|
raise
|
|
'';
|
|
}
|