Simon Gardling
d00ff42e8e
new site-config.nix holds values previously duplicated across hosts:
domain, old_domain, contact_email, timezone, binary_cache (url + pubkey),
dns_servers, lan (cidr + gateway), hosts.{muffin,yarn} (ip/alias/ssh_host_key),
ssh_keys.{laptop,desktop,ci_deploy}.
threaded through specialArgs on all three hosts + home-manager extraSpecialArgs +
homeConfigurations.primary + serverLib. service-configs.nix now takes
{ site_config } as a function arg and drops its https namespace; per-service
domains (gitea/matrix/ntfy/mollysocket/livekit/firefox-sync/grafana) are
derived from site_config.domain. ~15 service files and 6 vm tests migrated.
breakage fixes rolled in:
- home/progs/zen/dark-reader.nix: 5 stale *.gardling.com entries in
disabledFor rewritten to *.sigkill.computer (caddy 301s the old names so
these never fired and the new sigkill urls were getting dark-reader applied)
- modules/desktop-common.nix: drop unused hugepagesz=1G/hugepages=3
kernelParams (no consumer on mreow or yarn; xmrig on muffin still reserves
its own via services/monero/xmrig.nix)
verification: muffin toplevel is bit-identical to pre-refactor baseline.
mreow/yarn toplevels differ only in boot.json kernelParams + darkreader
storage.js (nix-diff verified). deployGuardTest and fail2banVaultwardenTest
(latter exercises site_config.domain via bitwarden.nix) pass.
68 lines
2.0 KiB
Nix
68 lines
2.0 KiB
Nix
{
|
|
pkgs,
|
|
config,
|
|
site_config,
|
|
service_configs,
|
|
lib,
|
|
...
|
|
}:
|
|
{
|
|
imports = [
|
|
(lib.serviceMountWithZpool "jellyfin" service_configs.zpool_ssds [
|
|
config.services.jellyfin.dataDir
|
|
config.services.jellyfin.cacheDir
|
|
])
|
|
(lib.serviceFilePerms "jellyfin" [
|
|
"Z ${config.services.jellyfin.dataDir} 0700 ${config.services.jellyfin.user} ${config.services.jellyfin.group}"
|
|
"Z ${config.services.jellyfin.cacheDir} 0700 ${config.services.jellyfin.user} ${config.services.jellyfin.group}"
|
|
])
|
|
];
|
|
|
|
services.jellyfin = {
|
|
enable = true;
|
|
package = pkgs.jellyfin.override { jellyfin-ffmpeg = (lib.optimizePackage pkgs.jellyfin-ffmpeg); };
|
|
|
|
inherit (service_configs.jellyfin) dataDir cacheDir;
|
|
};
|
|
|
|
services.caddy.virtualHosts."jellyfin.${site_config.domain}".extraConfig = ''
|
|
reverse_proxy :${builtins.toString service_configs.ports.private.jellyfin.port} {
|
|
# Disable response buffering for streaming. Caddy's default partial
|
|
# buffering delays fMP4-HLS segments and direct-play responses where
|
|
# Content-Length is known (so auto-flush doesn't trigger).
|
|
flush_interval -1
|
|
transport http {
|
|
# Localhost: compression wastes CPU re-encoding already-compressed media.
|
|
compression off
|
|
}
|
|
header_up X-Real-IP {remote_host}
|
|
header_up X-Forwarded-For {remote_host}
|
|
header_up X-Forwarded-Proto {scheme}
|
|
}
|
|
request_body {
|
|
max_size 4096MB
|
|
}
|
|
'';
|
|
|
|
users.users.${config.services.jellyfin.user}.extraGroups = [
|
|
"video"
|
|
"render"
|
|
service_configs.media_group
|
|
];
|
|
|
|
# Protect Jellyfin login from brute force attacks
|
|
services.fail2ban.jails.jellyfin = {
|
|
enabled = true;
|
|
settings = {
|
|
backend = "auto";
|
|
port = "http,https";
|
|
logpath = "${config.services.jellyfin.dataDir}/log/log_*.log";
|
|
# defaults: maxretry=5, findtime=10m, bantime=10m
|
|
};
|
|
filter.Definition = {
|
|
failregex = ''^.*Authentication request for .* has been denied \(IP: "<ADDR>"\)\..*$'';
|
|
ignoreregex = "";
|
|
};
|
|
};
|
|
}
|